{ self, ... }:
{
  perSystem =
    { ... }:
    {
      websites.${self.domain} =
        { lib, ... }:
        let
          inherit (lib) mkOption types;
        in
        {
          options = {
            # Erweiterung zwecks ad-hoc templating
            events = mkOption {
              type =
                with types;
                attrsOf (
                  submodule (
                    { name, ... }:
                    {
                      options.name = mkOption {
                        type = str;
                        readOnly = true;
                        default = name;
                      };
                      options.__toString = mkOption {
                        type = functionTo str;
                        readOnly = true;
                        default = self: ''
                          <dt id="${self.name}"><a href="#${self.name}">${self.title}</a></dt>
                          <dd>
                            <time datetime="${self.date.start} ${self.time.start}">${
                              # TODO: Lokalisierte Zeitdarstellung
                              self.datetime-range-text
                            }</time>

                            <address>
                              ${self.address.name}<br>
                              <a target="_blank" href="${
                                let
                                  type = with lib; head (attrNames self.address.openstreetmap);
                                  id = self.address.openstreetmap.${type};
                                in
                                "https://www.openstreetmap.org/${type}/${toString id}"
                              }">${with lib; concatStringsSep ", " (splitString "\n" (trim self.address.text))}</a>
                            </address>

                            ${
                              if !isNull self.summary then
                                ''
                                  <details><summary>${self.summary}</summary>
                                  ${self.description}
                                  </details>
                                ''
                              else if !isNull self.description then
                                ''
                                  ${self.description}
                                ''
                              else
                                ""
                            }

                            ${lib.optionalString (!isNull self.aside) ''<aside class="highlight-box">${self.aside}</aside>''}

                            ${
                              with lib;
                              optionalString (self.data != [ ]) ''
                                <dl>
                                  ${concatMapStringsSep "\n" (entry: ''
                                    <dt>${entry.name}</dt>
                                    <dd>${entry.value}</dd>
                                  '') self.data}
                                </dl>
                              ''
                            }

                            ${
                              with lib;
                              let
                                print-host = host: ''<a target="_blank" href="${host.url}">${host.name}</a>'';
                              in
                              if self.hosts == [ ] then
                                ""
                              else if length self.hosts == 1 then
                                ''
                                  <p>Veranstalter: ${print-host (head self.hosts)}</p>
                                ''
                              else
                                ''
                                  <p>Veranstalter:
                                  <ul>
                                    ${concatMapStringsSep "\n" (host: ''
                                      <li>${print-host host}</li>
                                    '') self.hosts}
                                  </ul>
                                  </p>
                                ''
                            }

                            ${
                              with lib;
                              let
                                print-link =
                                  link:
                                  ''<a ${optionalString link.external ''target="_blank" ''}href="${link.url}">${link.text}</a>'';
                              in
                              if self.links == [ ] then
                                ""
                              else if length self.links == 1 then
                                ''
                                  <p>Weitere Informationen: ${print-link (head self.links)}</p>
                                ''
                              else
                                ''
                                  <p>Weitere Informationen:
                                  <ul>
                                    ${concatMapStringsSep "\n" (link: ''
                                      <li>${print-link link}</li>
                                    '') self.links}
                                  </ul>
                                  </p>
                                ''
                            }
                          </dd>
                        '';
                      };
                    }
                  )
                );
            };
          };
        };
    };
}