1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
|
{
self,
config,
lib,
...
}:
let
inherit (lib) mkOption types;
in
{
options.flake.machines = mkOption {
description = ''
Hilfswerkzeuge um Rechner mit NixOS neu aufzusetzen und zu verwalten
`networking.hostName` wird standardmäßig auf den Attributnamen der Maschine gesetzt.
'';
type =
with types;
attrsOf (
submodule (
machine@{ name, options, ... }:
{
options = {
bootstrap-target = mkOption {
description = ''
SSH-Verbindung fürs Aufsetzen der Maschine
Die jeweilige Maschine wird einen vorhandenen Authentifikationsmechanismus haben, z.b. SSH-Key oder Passwort, der hierfür beim Aufruf einmalig manuell genutzt wird.
'';
type = types.str;
example = "root@example.org";
};
deploy-target = mkOption {
description = ''
SSH-Verbindung für reguläres Verwaltung der Maschine
Die Authentifizierung erfolg entsprechend der Maschinenkonfiguration, und Admins sollten die Verbindungsdaten bei sich entsprechend einrichten, z.B. über `~/.ssh/config`.
'';
type = types.str;
example = "user@example.org";
default = machine.config.bootstrap-target;
};
nixos = mkOption {
description = ''
NixOS Konfigurationsmodul für die Maschine
Dokumentation: <https://search.nixos.org/options>
'';
type =
with types;
deferredModuleWith {
staticModules = [
{
_class = "nixos";
networking.hostName = lib.mkDefault machine.name;
}
];
};
};
vm = mkOption {
description = ''
Konfigurationsmodul zur virtuellen Maschine (VM) für lokale Tests
Abgesehen von den hier festgelegten Einstellungen und Datenbankinhalten enspricht die virtuelle Maschine genau dem Produktionssystem.
Dies erlaubt recht zuverlässige manuelle Prüfung der Konfiguration im Vorfeld von Änderungen am Produktionssystem.
Maschinenspezifische VM-Einstellungen werden mit den hier vorgegebenen Standardwerten zusammengefügt.
Bei Bedarf müssen die Standards explizit mit `lib.mkForce` überschrieben werden.
'';
type = types.deferredModuleWith {
staticModules = [ options.vm.default ];
};
default =
{
config,
options,
modulesPath,
lib,
...
}:
{
_class = "nixos";
imports = [
"${modulesPath}/virtualisation/qemu-vm.nix"
];
options = {
virtualisation.portOffset = mkOption {
description = ''
An den VM-Host exponierte Portnummern von Diensten innerhalb der VM um diesen Wert versetzen
Dies dient dazu, Konflikte mit möglicherweise bestehenden Diensten auf dem Host zu vermeiden.
Beispiel: SSH auf Port 22 in der VM wird beim Host exponiert auf Port ${
toString (22 + options.virtualisation.portOffset.default)
}.
'';
type = types.ints.positive;
default = 10000;
};
};
config = {
virtualisation.forwardPorts = map (port: {
from = "host";
guest.port = port;
host.port = port + config.virtualisation.portOffset;
proto = "tcp";
}) config.networking.firewall.allowedTCPPorts;
services.getty.autologinUser = lib.mkDefault "root";
};
};
};
eval = mkOption {
readOnly = true;
internal = true;
default = lib.nixosSystem {
modules = [ machine.config.nixos ];
};
};
vm-eval = mkOption {
readOnly = true;
internal = true;
default = lib.nixosSystem {
modules = [
machine.config.nixos
machine.config.vm
];
};
};
};
}
)
);
};
config.flake.nixosConfigurations = lib.mapAttrs (name: machine: machine.eval) self.machines;
config.perSystem =
{ pkgs, ... }:
{
/*
Projektweite Tests, ausführen mit:
nix flake check
*/
checks = lib.concatMapAttrs (name: machine: {
/*
Konsistenzprüfung der Partitionierung.
Erfolgreicher Test bedeutet nicht unbedingt, dass die Konfiguration auch in der Produktionsumgebung funktioniert.
Beispielsweise muss die Konfiguration dazu passen, ob das Produktionssystem mit BIOS oder UEFI bootet.
*/
"${name}-installTest" = machine.eval.config.system.build.installTest;
}) self.machines;
# Werkzeuge zur Verwaltung von Maschinen
packages = lib.concatMapAttrs (name: machine: {
"infect-${name}" = pkgs.writeShellApplication {
name = "infect";
runtimeInputs = with pkgs; [ nixos-anywhere ];
/*
ACHTUNG: Vor dem Aufsetzen erst Informationen zur Hardware abfragen und in die Konfiguration einbetten!
nix run .#machines.infect-<machine> -- --no-reboot --generate-hardware-config nixos-hardware-config <datei>
*/
text = ''
nixos-anywhere --store-paths \
${machine.eval.config.system.build.diskoScript} \
${machine.eval.config.system.build.toplevel} \
${machine.bootstrap-target} "$@"
'';
};
"deploy-${name}" = pkgs.writeShellApplication {
name = "deploy";
text =
let
system = machine.eval.config.system.build.toplevel;
in
''
${
"" # XXX: Keine Signaturen. Das richtig einzurichten ist für den Moment zu umständlich.
}nix copy --to ssh-ng://${machine.deploy-target} --no-check-sigs ${system}
# shellcheck disable=SC2087
${
""
/*
ACHTUNG: Admins sollten sicherstellen, dass für diesen Host in `~/.ssh/config` folgendes enthalten ist:
ForwardAgent: yes
Außerdem muss der dort konfigurierte Nutzer dem Nutzer auf der jeweiligen Maschine enstprechen, und der SSH-Key zum SSH-Agent hinzugefügt sein.
Es gibt keine Passwörter und auch keine Möglichkeit eins einzugeben.
*/
}ssh ${machine.deploy-target} << EOF
sudo nix-env -p /nix/var/nix/profiles/system --set ${system}
sudo ${system}/bin/switch-to-configuration "$@"
EOF
'';
};
"vm-${name}" = pkgs.writeShellApplication {
name = "vm";
text = ''
${
"" # Festplattenabbild im flüchtigen Speicher erstellen, das ist deutlich schneller
}cd "$(mktemp -d)"
${
"" # Immer am Ende aufräumen
}trap 'rm -f nixos.qcow2' EXIT
${lib.getExe machine.vm-eval.config.system.build.vm} "$@"
'';
};
}) self.machines;
};
}
|
